AM Modulator
This circuit uses two signal generators to simulate an Amplitude Modulated RF carrier wave. The output can be used to simulate the response of LC and tank circuits.

Notes
Two signal generators are used in this circuit, one representing a high frequency (200kHz) RF carrier, VG2, the other signal generator is used to inject a 1KHz audio signal. The two signals are mixed and amplified by the transistor and an amplitude modulated signal appears at the collector of the BC548. The DC component is removed by C2 and R3 and the RF output now appears across the load resistor R3. Waveforms below are produced using Tina.



Spice Netlist
The spice netlist is shown below. Copy all lines between *AM and .END and paste into a new text file called vmod.cir or similar.

*AM RF modulator
.AC DEC 16 1 1.0MEG
.TRAN 4U 2M
.DC LIN VG2 0 1 10M
.PLOT V(3)
Vcc 1 0 30
VG2 2 0 DC 0 AC 1 0 SIN( 0 10M 200K 0 0 -90 )
VG1 4 0 DC 0 AC 1 0 SIN( 0 5 1K 0 0 -90 )
C3 5 0 100N
C2 6 3 470P
C1 2 7 100N
R5 0 7 15K
R4 7 1 56K
R3 0 3 1K
R2 4 5 4.7K
R1 1 6 10K
QT1 6 7 5 Q_BC548_N
.MODEL Q_BC548_N NPN( IS=16.9F NF=1 NR=1 RE=567M RC=1
+ RB=10 VAF=56.7 VAR=28.3 ISE=154F ISC=154F
+ NE=1.5 NC=1.5 BF=1.16K BR=5 IKF=29.5M
+ IKR=29.5M CJC=3.35P CJE=6.85P VJC=3.57 VJE=1.09
+ MJC=489M MJE=432M TF=796P TR=103N EG=1.11
+ KF=0 AF=1 )
.END

To produce an output in Spice Opus start the program and load the new vmod.cir The modulated signal appears across R3 which is now node 3 and earth. After loading the circuit the command "listing" will display the netlist. The command "run" will then simulate the circuit, "display" will print a list of all variables in the circuit. The command plot v(3) will display the AM wave between node 3 and 0 i.e. the load resistor R3.



Note to speed up simulation, the RF carrier has been limited to 200KHz only, and the output waveform just shows two complete cycles of the audio wave, i.e. 2ms as the modulating frequency is 1k. There will be some spice tutorials shortly on my pages.